0cb3946ee7
M main/Main.hs M main/Repl.hs M src/Nix/Builtins.hs M src/Nix/Convert.hs M src/Nix/Effects.hs M src/Nix/Effects/Basic.hs M src/Nix/Eval.hs M src/Nix/Exec.hs M src/Nix/Expr/Types.hs M src/Nix/Json.hs M src/Nix/Lint.hs M src/Nix/Normal.hs M src/Nix/Options/Parser.hs M src/Nix/Parser.hs M src/Nix/Scope.hs M src/Nix/String.hs M src/Nix/TH.hs M src/Nix/Thunk/Basic.hs M src/Nix/Utils.hs M src/Nix/Value.hs M src/Nix/Value/Equal.hs M src/Nix/XML.hs M tests/EvalTests.hs M tests/Main.hs M tests/NixLanguageTests.hs M tests/ParserTests.hs M tests/TestCommon.hs
57 lines
1.9 KiB
Haskell
57 lines
1.9 KiB
Haskell
{-# LANGUAGE FlexibleContexts #-}
|
|
{-# LANGUAGE OverloadedStrings #-}
|
|
{-# LANGUAGE LambdaCase #-}
|
|
|
|
module Nix.Json where
|
|
|
|
import Control.Monad
|
|
import Control.Monad.Trans
|
|
import qualified Data.Aeson as A
|
|
import qualified Data.Aeson.Encoding as A
|
|
import qualified Data.HashMap.Lazy as HM
|
|
import qualified Data.Text as Text
|
|
import qualified Data.Text.Lazy as TL
|
|
import qualified Data.Text.Lazy.Encoding as TL
|
|
import qualified Data.Vector as V
|
|
import Nix.Atoms
|
|
import Nix.Effects
|
|
import Nix.Exec
|
|
import Nix.Frames
|
|
import Nix.String
|
|
import Nix.Utils
|
|
import Nix.Value
|
|
import Nix.Value.Monad
|
|
|
|
nvalueToJSONNixString :: MonadNix e t f m => NValue t f m -> m NixString
|
|
nvalueToJSONNixString =
|
|
runWithStringContextT
|
|
. fmap
|
|
( TL.toStrict
|
|
. TL.decodeUtf8
|
|
. A.encodingToLazyByteString
|
|
. toEncodingSorted
|
|
)
|
|
. nvalueToJSON
|
|
|
|
nvalueToJSON :: MonadNix e t f m => NValue t f m -> WithStringContextT m A.Value
|
|
nvalueToJSON = \case
|
|
NVConstant (NInt n) -> pure $ A.toJSON n
|
|
NVConstant (NFloat n) -> pure $ A.toJSON n
|
|
NVConstant (NBool b) -> pure $ A.toJSON b
|
|
NVConstant NNull -> pure $ A.Null
|
|
NVStr ns -> A.toJSON <$> extractNixString ns
|
|
NVList l ->
|
|
A.Array
|
|
. V.fromList
|
|
<$> traverse (join . lift . flip demand (pure . nvalueToJSON)) l
|
|
NVSet m _ -> case HM.lookup "outPath" m of
|
|
Nothing ->
|
|
A.Object
|
|
<$> traverse (join . lift . flip demand (pure . nvalueToJSON)) m
|
|
Just outPath -> join $ lift $ demand outPath (pure . nvalueToJSON)
|
|
NVPath p -> do
|
|
fp <- lift $ unStorePath <$> addPath p
|
|
addSingletonStringContext $ StringContext (Text.pack fp) DirectPath
|
|
pure $ A.toJSON fp
|
|
v -> lift $ throwError $ CoercionToJson v
|