a7123f0edf
1999-10-01 Andreas Jaeger <aj@suse.de> * locale/programs/ld-collate.c (insert_value): Add cast to avoid warning. * intl/finddomain.c (_nl_find_domain): Likewise. 1999-09-30 Andreas Schwab <schwab@suse.de> * sysdeps/unix/sysv/linux/alpha/ioperm.c: Disable debug messages. 1999-09-30 Andreas Jaeger <aj@suse.de> * sysdeps/i386/lshift.S: Correct assembler commands to fix warnings. * sysdeps/i386/rshift.S: Likewise. * sysdeps/i386/strchrnul.S: Likewise. * sysdeps/i386/strchr.S: Likewise. Patch by Michael Deutschmann <michael@talamasca.wkpowerlink.com>, PR libc/1339. 1999-09-30 Andreas Jaeger <aj@suse.de> * manual/examples/pipe.c: Close other end of pipe to make example work. 1999-10-01 Ulrich Drepper <drepper@cygnus.com> * timezone/checktab.awk: Update from tzcode1999g. * timezone/tzselect.ksh: Likewise. * timezone/africa: Update from tzdata1999g. * timezone/asia: Likewise. * timezone/australasia: Likewise. * timezone/europe: Likewise. * timezone/northamerica: Likewise. * timezone/southamerica: Likewise. * timezone/iso3166.tab: Likewise. * timezone/zone.tab: Likewise. been renamed to getipnodebyname. Move flags around.
85 lines
2.1 KiB
ArmAsm
85 lines
2.1 KiB
ArmAsm
/* i80386 __mpn_rshift --
|
|
Copyright (C) 1992, 1994, 1997, 1998, 1999 Free Software Foundation, Inc.
|
|
This file is part of the GNU MP Library.
|
|
|
|
The GNU MP Library is free software; you can redistribute it and/or modify
|
|
it under the terms of the GNU Library General Public License as published by
|
|
the Free Software Foundation; either version 2 of the License, or (at your
|
|
option) any later version.
|
|
|
|
The GNU MP Library is distributed in the hope that it will be useful, but
|
|
WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
|
|
or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Library General Public
|
|
License for more details.
|
|
|
|
You should have received a copy of the GNU Library General Public License
|
|
along with the GNU MP Library; see the file COPYING.LIB. If not, write to
|
|
the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
|
|
MA 02111-1307, USA. */
|
|
|
|
/*
|
|
INPUT PARAMETERS
|
|
res_ptr (sp + 4)
|
|
s_ptr (sp + 8)
|
|
size (sp + 12)
|
|
cnt (sp + 16)
|
|
*/
|
|
|
|
#include "sysdep.h"
|
|
#include "asm-syntax.h"
|
|
|
|
.text
|
|
ENTRY(__mpn_rshift)
|
|
pushl %edi
|
|
pushl %esi
|
|
pushl %ebx
|
|
|
|
movl 16(%esp),%edi /* res_ptr */
|
|
movl 20(%esp),%esi /* s_ptr */
|
|
movl 24(%esp),%edx /* size */
|
|
movl 28(%esp),%ecx /* cnt */
|
|
|
|
leal -4(%edi,%edx,4),%edi
|
|
leal (%esi,%edx,4),%esi
|
|
negl %edx
|
|
|
|
movl (%esi,%edx,4),%ebx /* read least significant limb */
|
|
xorl %eax,%eax
|
|
shrdl %cl,%ebx,%eax /* compute carry limb */
|
|
incl %edx
|
|
jz L(end)
|
|
pushl %eax /* push carry limb onto stack */
|
|
testb $1,%dl
|
|
jnz L(1) /* enter loop in the middle */
|
|
movl %ebx,%eax
|
|
|
|
ALIGN (3)
|
|
L(oop): movl (%esi,%edx,4),%ebx /* load next higher limb */
|
|
shrdl %cl,%ebx,%eax /* compute result limb */
|
|
movl %eax,(%edi,%edx,4) /* store it */
|
|
incl %edx
|
|
L(1): movl (%esi,%edx,4),%eax
|
|
shrdl %cl,%eax,%ebx
|
|
movl %ebx,(%edi,%edx,4)
|
|
incl %edx
|
|
jnz L(oop)
|
|
|
|
shrl %cl,%eax /* compute most significant limb */
|
|
movl %eax,(%edi) /* store it */
|
|
|
|
popl %eax /* pop carry limb */
|
|
|
|
popl %ebx
|
|
popl %esi
|
|
popl %edi
|
|
ret
|
|
|
|
L(end): shrl %cl,%ebx /* compute most significant limb */
|
|
movl %ebx,(%edi) /* store it */
|
|
|
|
popl %ebx
|
|
popl %esi
|
|
popl %edi
|
|
ret
|
|
END(__mpn_rshift)
|