61c83c3f05
to ensure a sane installation. (mach_interface_list): Define this variable by checking for .defs files found in various variants. * configure.in (mach_interface_list): AC_SUBST this. * config.make.in (mach-interface-list): New substituted variable. * mach/Makefile (user-interfaces): Define this using the value of $(mach-interface-list) instead of mach, mach4. Updated other references to mach_interface to use it as well. * sysdeps/mach/powerpc/machine-lock.h: Avoid multi-line strings. * mach/msgserver.c [NDR_CHAR_ASCII] (mig_reply_header_t): #define as mig_reply_error_t for OSF Mach variant. * mach/Makefile (routines): Remove bootprivport. * mach/bootprivport.c: File removed. It has never been used. * mach/msg-destroy.c (__mach_msg_destroy) [MACH_MSG_PORT_DESCRIPTOR]: Grok the OSF flavor of message format. (mach_msg_destroy_port): For MAKE_SEND and MAKE_SEND_ONCE rights, create an destroy a right to ensure proper no-senders notification. 2002-02-06 Roland McGrath <roland@frob.com> * hurd/Versions (libc: GLIBC_2.0): Move cthread_fork, cthread_detach to here if 2.0 compatibility enabled ... (libc: GLIBC_2.1.3): ... from here.
62 lines
2.1 KiB
Plaintext
62 lines
2.1 KiB
Plaintext
sinclude(./aclocal.m4)dnl Autoconf lossage.
|
|
GLIBC_PROVIDES dnl See aclocal.m4 in the top level source directory.
|
|
|
|
### Sanity checks for Mach header installation
|
|
AC_CHECK_HEADER(mach/mach_types.h,, [AC_MSG_ERROR([cannot find Mach headers])])
|
|
AC_CHECK_HEADER(mach/mach_types.defs,, [dnl
|
|
AC_MSG_ERROR([cannot find Mach .defs files])])
|
|
|
|
dnl
|
|
dnl mach_TYPE_CHECK(foo_t, bar_t)
|
|
dnl
|
|
dnl Check if foo_t is defined by <mach/mach_types.h>.
|
|
dnl If not, compile with -Dfoo_t=bar_t.
|
|
dnl
|
|
AC_DEFUN([mach_TYPE_CHECK], [dnl
|
|
AC_CACHE_CHECK(for $1 in mach/mach_types.h, libc_cv_mach_$1,
|
|
AC_TRY_COMPILE([#include <mach/mach_types.h>], [extern $1 foo;],
|
|
libc_cv_mach_$1=$1, libc_cv_mach_$1=$2))
|
|
if test [$]libc_cv_mach_$1 != $1; then
|
|
DEFINES="$DEFINES -D$1=$2"
|
|
fi])
|
|
|
|
dnl
|
|
dnl OSF Mach has renamed these typedefs for some reason.
|
|
dnl
|
|
mach_TYPE_CHECK(task_t, task_port_t)
|
|
mach_TYPE_CHECK(thread_t, thread_port_t)
|
|
|
|
dnl
|
|
dnl The creation_time field is a GNU Mach addition the other variants lack.
|
|
dnl
|
|
AC_CACHE_CHECK(for creation_time in task_basic_info,
|
|
libc_cv_mach_task_creation_time, [dnl
|
|
AC_TRY_COMPILE([#include <mach/task_info.h>], [
|
|
extern struct task_basic_info *i;
|
|
long s = i->creation_time.seconds;
|
|
], libc_cv_mach_task_creation_time=yes, libc_cv_mach_task_creation_time=no)])
|
|
if test $libc_cv_mach_task_creation_time = no; then
|
|
DEFINES="$DEFINES -DNO_CREATION_TIME=1"
|
|
fi
|
|
|
|
dnl
|
|
dnl The Darwin variant no longer has <mach/mach.defs>
|
|
dnl but instead has several constituent .defs files.
|
|
dnl In this scenario we will presume there is a <mach/mach_interface.h>
|
|
dnl that contains an #include for each constituent header file,
|
|
dnl but we don't do a check for that here because in a bare
|
|
dnl environment the compile against those headers will fail.
|
|
dnl
|
|
mach_interface_list=
|
|
for ifc in mach mach4 \
|
|
clock_priv host_priv host_security ledger lock_set \
|
|
processor processor_set task thread_act vm_map \
|
|
memory_object memory_object_default default_pager \
|
|
; do
|
|
AC_CHECK_HEADER(mach/${ifc}.defs, [dnl
|
|
mach_interface_list="$mach_interface_list $ifc"])
|
|
done
|
|
if test "x$mach_interface_list" = x; then
|
|
AC_MSG_ERROR([what manner of Mach is this?])
|
|
fi
|