6d52618b15
Thu Dec 19 23:28:33 1996 Ulrich Drepper <drepper@cygnus.com> * resolv/resolv.h: Update from BIND 4.9.5-P1. * resolv/res_comp.c: Likewise. * resolv/res_debug.c: Likewise. * resolv/Banner: Update version number. Thu Dec 19 20:58:53 1996 Ulrich Drepper <drepper@cygnus.com> * elf/dlfcn.h: Add extern "C" wrapper. * io/utime.h: Don't define NULL since this isn't allowed in POSIX. * io/sys/stat.h: Declare `lstat' only if __USE_BSD || __USE_XOPEN_EXTENDED. * locale/locale.h: Define NULL. * math/math.c: Don't include <errno.h> to define math errors. * stdlib/stdlib.h: Likewise. * posix/unistd.h: Don't declare environ. * posix/sys/utsname.h (struct utsname): Declare member domainname as __domainname is !__USE_GNU. * signal/signal.h: Declare size_t only if __USE_BSD || __USE_XOPEN_EXTENDED. * stdio/stdio.h: Don't declare cuserid when __USE_POSIX, but instead when __USE_XOPEN. * string/string.h: Define strndup only if __USE_GNU. * sysdeps/unix/sysv/linux/clock.c: New file. * sysdeps/unix/sysv/linux/timebits.h: Define CLOCKS_PER_SEC as 1000000 per X/Open standard. * features.h: Add code to recognize _POSIX_C_SOURCE value 199309. Define __USE_POSIX199309. * posix/unistd.h: Declare fdatasync only if __USE_POSIX199309. * time/time.c: Declare nanosleep only if __USE_POSIX199309. Patches by Rüdiger Helsch <rh@unifix.de>. * locale/locale.h: Add declaration of newlocale and freelocale. * new-malloc/Makefile (distibute): Add mtrace.awk. (dist-routines): Add mcheck and mtrace. (install-lib, non-lib.a): Define as libmcheck.a. * new-malloc/malloc.h: Add declaration of __malloc_initialized. * new-malloc/mcheck.c: New file. * new-malloc/mcheck.h: New file. * new-malloc/mtrace.c: New file. * new-malloc/mtrace.awk: New file. * posix/unistd.h: Correct prototype for usleep. * sysdeps/unix/bsd/usleep.c: De-ANSI-declfy. Correct return type. * sysdeps/unix/sysv/linux/usleep.c: Real implementation based on nanosleep. * signal/signal.h: Change protoype of __sigpause to take two arguments. Remove prototype for sigpause. Add two different macros named sigpause selected when __USE_BSD or __USE_XOPEN are defined. This is necessary since the old BSD definition of theis function collides with the X/Open definition. * sysdeps/posix/sigpause.c: Change function definition to also fit X/Open definition. * sysdeps/libm-i387/e_exp.S: Make sure stack is empty when the function is left. * sysdeps/libm-i387/e_expl.S: Likewise. Patch by HJ Lu. 1996-12-17 Paul Eggert <eggert@twinsun.com> * many, many files: Spelling corrections. * catgets/catgetsinfo.h (mmapped): Renamed from mmaped (in struct catalog_info.status). * mach/err_kern.sub (err_codes_unix), string/stratcliff.c (main): Fix spelling in message. * po/libc.pot: Fix spelling in message for `zic'; this anticipates a fix in the tzcode distribution. Wed Dec 18 15:48:02 1996 Ulrich Drepper <drepper@cygnus.com> * time/strftime.c: Implement ^ flag to cause output be converted to use upper case characters. * time/zic.c: Update from ADO tzcode1996n. Wed Dec 18 14:29:24 1996 Erik Naggum <erik@naggum.no> * time/strftime.c (add): Don't change global `i' until all is over. Define NULL is not already defined. Tue Dec 17 09:49:03 1996 Andreas Schwab <schwab@issan.informatik.uni-dortmund.de> * libio/iovsprintf.c (_IO_vsprintf): Change `&sf' to `&sf._sbf._f' to avoid the need for a cast. * libio/iovsscanf.c (_IO_vsscanf): Likewise. * sunrpc/rpc/xdr.h: Add prototype for xdr_free.
178 lines
5 KiB
ArmAsm
178 lines
5 KiB
ArmAsm
/* strcspn (str, ss) -- Return the length of the initial segment of STR
|
|
which contains no characters from SS.
|
|
For Intel 80x86, x>=3.
|
|
Copyright (C) 1994, 1995, 1996 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
Contributed by Ulrich Drepper <drepper@gnu.ai.mit.edu>
|
|
Bug fixes by Alan Modra <Alan@SPRI.Levels.UniSA.Edu.Au>
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Library General Public License as
|
|
published by the Free Software Foundation; either version 2 of the
|
|
License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Library General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Library General Public
|
|
License along with the GNU C Library; see the file COPYING.LIB. If not,
|
|
write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
|
|
Boston, MA 02111-1307, USA. */
|
|
|
|
#include <sysdep.h>
|
|
#include "asm-syntax.h"
|
|
|
|
/*
|
|
INPUT PARAMETERS:
|
|
str (sp + 4)
|
|
stopset (sp + 8)
|
|
*/
|
|
|
|
.text
|
|
ENTRY (strcspn)
|
|
movl 4(%esp), %edx /* get string pointer */
|
|
movl 8(%esp), %eax /* get stopset pointer */
|
|
|
|
/* First we create a table with flags for all possible characters.
|
|
For the ASCII (7bit/8bit) or ISO-8859-X character sets which are
|
|
supported by the C string functions we have 256 characters.
|
|
Before inserting marks for the stop characters we clear the whole
|
|
table. The unrolled form is much faster than a loop. */
|
|
xorl %ecx, %ecx /* %ecx = 0 !!! */
|
|
|
|
pushl %ecx /* make a 256 bytes long block filled with 0 */
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl %ecx
|
|
pushl $0 /* These immediate values make the label 2 */
|
|
pushl $0 /* to be aligned on a 16 byte boundary to */
|
|
pushl $0 /* get a better performance of the loop. */
|
|
pushl $0
|
|
pushl $0
|
|
pushl $0
|
|
|
|
/* For understanding the following code remember that %ecx == 0 now.
|
|
Although all the following instruction only modify %cl we always
|
|
have a correct zero-extended 32-bit value in %ecx. */
|
|
|
|
/* Don't change the "testb $0xff,%%cl" to "testb %%cl,%%cl". We want
|
|
longer instructions so that the next loop aligns without adding nops. */
|
|
|
|
L2: movb (%eax), %cl /* get byte from stopset */
|
|
testb %cl, %cl /* is NUL char? */
|
|
jz L1 /* yes => start compare loop */
|
|
movb %cl, (%esp,%ecx) /* set corresponding byte in stopset table */
|
|
|
|
movb 1(%eax), %cl /* get byte from stopset */
|
|
testb $0xff, %cl /* is NUL char? */
|
|
jz L1 /* yes => start compare loop */
|
|
movb %cl, (%esp,%ecx) /* set corresponding byte in stopset table */
|
|
|
|
movb 2(%eax), %cl /* get byte from stopset */
|
|
testb $0xff, %cl /* is NUL char? */
|
|
jz L1 /* yes => start compare loop */
|
|
movb %cl, (%esp,%ecx) /* set corresponding byte in stopset table */
|
|
|
|
movb 3(%eax), %cl /* get byte from stopset */
|
|
addl $4, %eax /* increment stopset pointer */
|
|
movb %cl, (%esp,%ecx) /* set corresponding byte in stopset table */
|
|
testb $0xff, %cl /* is NUL char? */
|
|
jnz L2 /* no => process next dword from stopset */
|
|
|
|
L1: leal -4(%edx), %eax /* prepare loop */
|
|
|
|
/* We use a neat trick for the following loop. Normally we would
|
|
have to test for two termination conditions
|
|
1. a character in the stopset was found
|
|
and
|
|
2. the end of the string was found
|
|
But as a sign that the character is in the stopset we store its
|
|
value in the table. But the value of NUL is NUL so the loop
|
|
terminates for NUL in every case. */
|
|
|
|
L3: addl $4, %eax /* adjust pointer for full loop round */
|
|
|
|
movb (%eax), %cl /* get byte from string */
|
|
cmpb %cl, (%esp,%ecx) /* is it contained in stopset? */
|
|
je L4 /* yes => return */
|
|
|
|
movb 1(%eax), %cl /* get byte from string */
|
|
cmpb %cl, (%esp,%ecx) /* is it contained in stopset? */
|
|
je L5 /* yes => return */
|
|
|
|
movb 2(%eax), %cl /* get byte from string */
|
|
cmpb %cl, (%esp,%ecx) /* is it contained in stopset? */
|
|
je L6 /* yes => return */
|
|
|
|
movb 3(%eax), %cl /* get byte from string */
|
|
cmpb %cl, (%esp,%ecx) /* is it contained in stopset? */
|
|
jne L3 /* yes => return */
|
|
|
|
incl %eax /* adjust pointer */
|
|
L6: incl %eax
|
|
L5: incl %eax
|
|
|
|
L4: subl %edx, %eax /* we have to return the number of valid
|
|
characters, so compute distance to first
|
|
non-valid character */
|
|
addl $256, %esp /* remove stopset */
|
|
|
|
ret
|
|
END (strcspn)
|