590b40f7ec
2004-09-07 Jakub Jelinek <jakub@redhat.com> * sysdeps/powerpc/powerpc64/configure.in: New file. * config.h.in (USE_PPC64_OVERLAPPING_OPD): Add. * configure.in (HAVE_ASM_GLOBAL_DOT_NAME): Remove. * sysdeps/powerpc/powerpc64/sysdep.h: Formatting. (OPD_ENT, BODY_LABEL, ENTRY_1, ENTRY_2, END_2, DOT_PREFIX, BODY_PREFIX): Define. (ENTRY, DOT_LABEL, END, TRACEBACK, END_GEN_TB, EALIGN): Support HAVE_ASM_GLOBAL_DOT_NAME or no dot symbols, USE_PPC64_OVERLAPPING_OPD or never overlapping .opd entries. * sysdeps/powerpc/powerpc64/dl-machine.h: Include sysdep.h. (TRAMPOLINE_TEMPLATE, RTLD_START): Use the new sysdep.h macros.
43 lines
1.3 KiB
Plaintext
43 lines
1.3 KiB
Plaintext
GLIBC_PROVIDES dnl See aclocal.m4 in the top level source directory.
|
|
# Local configure fragment for sysdeps/powerpc/powerpc64.
|
|
|
|
# The Aix ld uses global .symbol_names instead of symbol_names
|
|
# and unfortunately early Linux PPC64 linkers use it as well.
|
|
AC_CACHE_CHECK(for support for omitting dot symbols,
|
|
libc_cv_omit_dot_syms, [dnl
|
|
libc_cv_omit_dot_syms=no
|
|
echo 'void foo (void) {}' > conftest.c
|
|
if AC_TRY_COMMAND(${CC-cc} $CFLAGS $CPPFLAGS -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
|
|
if grep -w '\.foo' conftest.s > /dev/null; then
|
|
:
|
|
else
|
|
libc_cv_omit_dot_syms=yes
|
|
fi
|
|
fi
|
|
rm -f conftest.c conftest.s
|
|
])
|
|
if test x$libc_cv_omit_dot_syms != xyes; then
|
|
AC_DEFINE(HAVE_ASM_GLOBAL_DOT_NAME)
|
|
fi
|
|
|
|
AC_CACHE_CHECK(for linker support for overlapping .opd entries,
|
|
libc_cv_overlapping_opd, [dnl
|
|
libc_cv_overlapping_opd=no
|
|
echo 'void foo (void) {}' > conftest.c
|
|
if AC_TRY_COMMAND(${CC-cc} $CFLAGS $CPPFLAGS -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
|
|
changequote(,)dnl
|
|
if grep '\.TOC\.@tocbase' conftest.s > /dev/null; then
|
|
if grep '\.TOC\.@tocbase[ ]*,[ ]*0' conftest.s > /dev/null; then
|
|
:
|
|
else
|
|
libc_cv_overlapping_opd=yes
|
|
fi
|
|
fi
|
|
changequote([,])dnl
|
|
fi
|
|
rm -f conftest.c conftest.s
|
|
])
|
|
if test x$libc_cv_overlapping_opd = xyes; then
|
|
AC_DEFINE(USE_PPC64_OVERLAPPING_OPD)
|
|
fi
|