2e65ca2b22
1999-07-06 Ulrich Drepper <drepper@cygnus.com> * sysdeps/unix/sysv/linux/alpha/ioperm.c: Update for some more motherboards. Patch by Jay Estabrook. * sysdeps/unix/sysv/linux/configure.in: Don't test for libc4 in ldd for SPARC. * /sysdeps/unix/sysv/linux/sparc/ldd-rewrite.sed: New file. Patch by Cristian Gafton. 1999-07-02 Cristian Gafton <gafton@redhat.com> * sysdeps/unix/sysv/linux/bits/socket.h (__cmsg_nxthdr): "return 0" instead of "return NULL" to make C++ happy. 1999-07-04 Mark Kettenis <kettenis@gnu.org> * libio/iofdopen.c (_IO_new_fdopen): Set EINVAL if MODE is not allowed by the file access mode of the open file. 1999-07-06 Ulrich Drepper <drepper@cygnus.com> * sysdeps/generic/setfpucw.c: Include math.h to get all needed macros defined. 1999-07-03 Jakub Jelinek <jj@ultra.linux.cz> * sysdeps/sparc/sparc64/submul_1.S: Fix carry handling. Optimize. * sysdeps/sparc/sparc64/lshift.S: Make a leaf subroutine. Optimize. * sysdeps/sparc/sparc64/rshift.S: Likewise. * sysdeps/sparc/sparc64/mul_1.S: Optimize. 1999-07-04 Wolfram Gloger <wmglo@dent.med.uni-muenchen.de> * malloc/malloc.c (request2size): Check for overflow and return NULL whenever it is encountered. 1999-07-04 Zack Weinberg <zack@rabi.columbia.edu> * sysdeps/posix/tempname.c (__gen_tempname): Add ability to create directories. Replace OPENIT and LARGEFILE args with a single flags parameter. * sysdeps/generic/tempname.c: Likewise. * include/stdio.h: Adjust prototype of __gen_tempname to match. Define symbolic constants for second argument. * misc/mkdtemp.c: New file, provides new function mkdtemp(). * stdlib/stdlib.h: Prototype it. * misc/Versions: Export it. * misc/Makefile (routines): Add mktemp. * manual/filesys.texi: Document it. * misc/mktemp.c: Adjust call of __gen_tempname to match new convention. * misc/mkstemp.c: Likewise. * stdio-common/tempnam.c: Likewise. * stdio-common/tmpfile.c: Likewise. * stdio-common/tmpfile64.c: Likewise. * stdio-common/tmpnam.c: Likewise. * stdio-common/tmpnam_r.c: Likewise. 1999-07-05 Jakub Jelinek <jj@ultra.linux.cz> * sysdeps/sparc/sparc64/dl-machine.h (elf_machine_rela): Support R_SPARC_OLO10 relocations. * elf/elf.h (R_SPARC_OLO10): Fix comment.
94 lines
2.1 KiB
ArmAsm
94 lines
2.1 KiB
ArmAsm
/* SPARC v9 __mpn_lshift --
|
|
|
|
Copyright (C) 1996, 1999 Free Software Foundation, Inc.
|
|
|
|
This file is part of the GNU MP Library.
|
|
|
|
The GNU MP Library is free software; you can redistribute it and/or modify
|
|
it under the terms of the GNU Library General Public License as published by
|
|
the Free Software Foundation; either version 2 of the License, or (at your
|
|
option) any later version.
|
|
|
|
The GNU MP Library is distributed in the hope that it will be useful, but
|
|
WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
|
|
or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Library General Public
|
|
License for more details.
|
|
|
|
You should have received a copy of the GNU Library General Public License
|
|
along with the GNU MP Library; see the file COPYING.LIB. If not, write to
|
|
the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
|
|
MA 02111-1307, USA. */
|
|
|
|
#include <sysdep.h>
|
|
|
|
/* INPUT PARAMETERS
|
|
res_ptr %o0
|
|
src_ptr %o1
|
|
size %o2
|
|
cnt %o3 */
|
|
|
|
ENTRY(__mpn_lshift)
|
|
sllx %o2,3,%g1
|
|
add %o1,%g1,%o1 ! make %o1 point at end of src
|
|
ldx [%o1-8],%g2 ! load first limb
|
|
sub %g0,%o3,%o5 ! negate shift count
|
|
add %o0,%g1,%o0 ! make %o0 point at end of res
|
|
add %o2,-1,%o2
|
|
andcc %o2,4-1,%g4 ! number of limbs in first loop
|
|
srlx %g2,%o5,%g1 ! compute function result
|
|
be,pn %xcc,.L0 ! if multiple of 4 limbs, skip first loop
|
|
mov %g1,%g5
|
|
|
|
sub %o2,%g4,%o2 ! adjust count for main loop
|
|
|
|
.Loop0: ldx [%o1-16],%g3
|
|
add %o0,-8,%o0
|
|
add %o1,-8,%o1
|
|
sllx %g2,%o3,%o4
|
|
addcc %g4,-1,%g4
|
|
srlx %g3,%o5,%g1
|
|
mov %g3,%g2
|
|
or %o4,%g1,%o4
|
|
bne,pt %xcc,.Loop0
|
|
stx %o4,[%o0+0]
|
|
|
|
.L0: brz,pn %o2,.Lend
|
|
nop
|
|
|
|
.Loop: ldx [%o1-16],%g3
|
|
add %o0,-32,%o0
|
|
sllx %g2,%o3,%o4
|
|
addcc %o2,-4,%o2
|
|
srlx %g3,%o5,%g1
|
|
|
|
ldx [%o1-24],%g2
|
|
sllx %g3,%o3,%g4
|
|
or %o4,%g1,%o4
|
|
stx %o4,[%o0+24]
|
|
srlx %g2,%o5,%g1
|
|
|
|
ldx [%o1-32],%g3
|
|
sllx %g2,%o3,%o4
|
|
or %g4,%g1,%g4
|
|
stx %g4,[%o0+16]
|
|
srlx %g3,%o5,%g1
|
|
|
|
ldx [%o1-40],%g2
|
|
sllx %g3,%o3,%g4
|
|
or %o4,%g1,%o4
|
|
stx %o4,[%o0+8]
|
|
srlx %g2,%o5,%g1
|
|
|
|
add %o1,-32,%o1
|
|
or %g4,%g1,%g4
|
|
bne,pt %xcc,.Loop
|
|
stx %g4,[%o0+0]
|
|
|
|
.Lend: sllx %g2,%o3,%g2
|
|
stx %g2,[%o0-8]
|
|
|
|
jmpl %o7+8, %g0
|
|
mov %g5,%o0
|
|
|
|
END(__mpn_lshift)
|